Function GetADDescription()

Die Funktion GetADdescription() ist eine Beispielfunktion, in der die Property Description für ein Computerobjekt abgefragt werden kann.

Function GetADDescription(strDomainDN, strServer)
    ON ERROR RESUME NEXT
    Dim strBase, strFilter, StrAttrs, strScope, strComputerDesc
    Dim objConn, objRS
     strBase = "<LDAP://" & strDomainDN & ">;"
     strFilter = "(&(objectCategory=computer)(cn=" & strServer & "));"
     strAttrs = "description" & ";"
     strScope = "subTree"
     GetADdescription=""
     set objConn = CreateObject("ADODB.Connection")
     objConn.Provider = "ADsDSOObject"
     objConn.Open "Active Directory Provider"
     Err.clear
     set objRS = objConn.Execute(strBase & strFilter & strAttrs & strScope)
    If Err.Number Then
        PrintLog Err.Number, strServer & ": ERROR ADODB at Set objRS = objConn.Execute(" & strBase & strFilter & strAttrs & strScope & ")"
        Err.Clear
        GetADdescription = "ERROR ADODB"
        Exit Function
    End If
    objRS.MoveFirst
    While Not objRS.EOF
        strComputerDesc = objRS.Fields("description").Value 'wird als Variant Array zurückgeliefert !?
        GetADdescription = strComputerDesc(0)
        objRS.MoveNext
    Wend
End Function
 
Die Property Description gibt es für alle AD Objekte, wie User, Gruppen, Computer, OUs etc.
 
Achtung!
Der Wert der Property Description ist ein String Array, darum muss mit strComputerDesc(0) auf das erste Element in dem Array zugegriffen werden.
 
Wenn mit dem Skript oben nach User Objekten gesucht werden soll, dann muss lediglich der Filter objectCategory=computer in objectCategory=user und der cn=Suchstring geändert werden.
Als Returnwert bekommen wir von GetADdescription() einen String mit dem Wert der Property "Description" des abgefragten Objekts.
 
Aufrufbeispiel: strDescrp = GetADdescription(GetDomainDN(), "Server01")